public function update():void {
   var request:URLRequest = new URLRequest("http://domain.com/yourapplication.air");
   var updater:AIRRemoteUpdater = new AIRRemoteUpdater();
   updater.addEventListener(AIRRemoteUpdaterEvent.VERSION_CHECK, updaterVersionCheckHandler);
   updater.addEventListener(AIRRemoteUpdaterEvent.UPDATE, updaterUpdateHandler);
   updater.update(request);
}
 
protected function updaterVersionCheckHandler(event:AIRRemoteUpdaterEvent):void {
   // The AIRRemoteUpdaterEvent.VERSION_CHECK event is fired
   // as soon as both local and remote version numbers are known. 
   var updater:AIRRemoteUpdater = event.target as AIRRemoteUpdater;
   trace("Local version: " + updater.localVersion);
   trace("Remote version: " + updater.remoteVersion);
   // You can stop execution of AIR Remote Updater at this point 
   // by calling event.preventDefault(), for example to inform the user 
   // that a new version is available and/or ask if she likes to download 
   // and install it. When the user confirms, call AIRRemoteUpdater.update()
   // again with the versionCheck argument set to "false". This will
   // circumvent the version checking procedure and immediately
   // starts to download the remote .AIR installer file to a temporary
   // file on the user's harddisk.
}
 
protected function updaterUpdateHandler(event:AIRRemoteUpdaterEvent):void {
   // The AIRRemoteUpdaterEvent.UPDATE event is fired when
   // the remote .AIR installer file has finished downloading.
   // The event's "file" property contains a reference to the
   // temporary file on the user's harddisk.
   trace("Installer: " + event.file.nativePath);
   // You can stop execution of AIR Remote Updater at this point 
   // by calling event.preventDefault(), for example to inform the user 
   // that the application is about to shut down and update itself.
}